將某目錄下面包含子目錄中所有的exe加入防火牆封鎖

panaplat

將某目錄下面包含子目錄中所有的exe加入防火牆封鎖


這裡封鎖的話是 in/out 都封，就是這些 exe 檔完全不能連網
為什麼要這麼做，懂的都懂

1. 
   
2. 
   
3. @echo off
   
4. chcp 65001 >nul
   
5. setlocal enabledelayedexpansion
   
6. 
   
7. REM ======================================
   
8. REM   Firewall Rule Manager
   
9. REM   Author: Edward Tai
   
10. REM   Website: panaplat.com
    
11. REM   Date: 2025.12.14
    
12. REM ======================================
    
13. 
    
14. set "default_path=C:\Program Files\Adobe"
    
15. set "rule_prefix=BlockExe_Panaplat_"
    
16. 
    
17. :menu
    
18. cls
    
19. echo ======================================
    
20. echo   Firewall Rule Manager
    
21. echo ======================================
    
22. echo   Author: Edward Tai
    
23. echo   Website: panaplat.com
    
24. echo   Date: 2025.12.14
    
25. echo ======================================
    
26. echo.
    
27. echo [1] Add Block Rules
    
28. echo [2] Delete All Rules
    
29. echo [3] Open Firewall Settings
    
30. echo [4] Exit
    
31. echo.
    
32. set /p choice=Select (1-4):
    
33. 
    
34. if "%choice%"=="1" goto add_rules
    
35. if "%choice%"=="2" goto delete_rules
    
36. if "%choice%"=="3" goto open_firewall
    
37. if "%choice%"=="4" exit /b
    
38. goto menu
    
39. 
    
40. :add_rules
    
41. cls
    
42. set "target_path="
    
43. echo Default Path: %default_path%
    
44. set /p target_path=Enter target path (Press Enter for default):
    
45. 
    
46. if "!target_path!"=="" set "target_path=%default_path%"
    
47. 
    
48. if not exist "!target_path!" (
    
49.     echo Error: Path not found
    
50.     pause
    
51.     goto menu
    
52. )
    
53. 
    
54. echo.
    
55. echo Scanning: !target_path!
    
56. echo.
    
57. 
    
58. set count=0
    
59. pushd "!target_path!"
    
60. for /r %%f in (*.exe) do (
    
61.     set "exe_path=%%f"
    
62.     set "exe_name=%%~nxf"
    
63.    
    
64.     for %%d in (in out) do (
    
65.         set /a count+=1
    
66.         echo [!count!] Adding %%d rule: !exe_name!
    
67.         netsh advfirewall firewall add rule name="%rule_prefix%!exe_name!" dir=%%d action=block program="!exe_path!" enable=yes >nul
    
68.     )
    
69. )
    
70. popd
    
71. 
    
72. if !count!==0 (
    
73.     echo No EXE files found!
    
74. )
    
75. 
    
76. echo.
    
77. echo Total: !count! rules added
    
78. pause
    
79. goto menu
    
80. 
    
81. :delete_rules
    
82. cls
    
83. echo Delete all block rules? (Y/N)
    
84. set /p confirm=
    
85. 
    
86. if /i "!confirm!"=="Y" (
    
87.     echo.
    
88.     echo Deleting all %rule_prefix% rules...
    
89.     echo.
    
90.    
    
91.     set count=0
    
92.     for /f "tokens=*" %%i in ('netsh advfirewall firewall show rule name^=all ^| findstr /I "%rule_prefix%" ^| findstr /V "@{"') do (
    
93.         for /f "usebackq tokens=2 delims=:" %%j in ('echo %%i') do (
    
94.             for /f "tokens=*" %%k in ("%%j") do (
    
95.                 set /a count+=1
    
96.                 echo [!count!] Deleting: %%k
    
97.                 netsh advfirewall firewall delete rule name="%%k"
    
98.             )
    
99.         )
    
100.     )
     
101.    
     
102.     if !count!==0 (
     
103.         echo No rules found!
     
104.     ) else (
     
105.         echo.
     
106.         echo Total: !count! rules deleted
     
107.     )
     
108. ) else (
     
109.     echo Cancelled
     
110. )
     
111. pause
     
112. goto menu
     
113. 
     
114. :open_firewall
     
115. start wf.msc
     
116. goto menu
     
117. 
     

複製代碼