將某目錄下面包含子目錄中所有的exe加入防火牆封鎖

panaplat · 發表於前天 21:12

將某目錄下面包含子目錄中所有的exe加入防火牆封鎖

這裡封鎖的話是 in/out 都封，就是這些 exe 檔完全不能連網
為什麼要這麼做，懂的都懂

@echo off
chcp 65001 >nul
setlocal enabledelayedexpansion
REM ======================================
REM Firewall Rule Manager
REM Author: Edward Tai
REM Website: panaplat.com
REM Date: 2025.12.14
REM ======================================
set "default_path=C:\Program Files\Adobe"
set "rule_prefix=BlockExe_Panaplat_"
:menu
cls
echo ======================================
echo Firewall Rule Manager
echo ======================================
echo Author: Edward Tai
echo Website: panaplat.com
echo Date: 2025.12.14
echo ======================================
echo.
echo [1] Add Block Rules
echo [2] Delete All Rules
echo [3] Open Firewall Settings
echo [4] Exit
echo.
set /p choice=Select (1-4):
if "%choice%"=="1" goto add_rules
if "%choice%"=="2" goto delete_rules
if "%choice%"=="3" goto open_firewall
if "%choice%"=="4" exit /b
goto menu
:add_rules
cls
set "target_path="
echo Default Path: %default_path%
set /p target_path=Enter target path (Press Enter for default):
if "!target_path!"=="" set "target_path=%default_path%"
if not exist "!target_path!" (
echo Error: Path not found
pause
goto menu
)
echo.
echo Scanning: !target_path!
echo.
set count=0
pushd "!target_path!"
for /r %%f in (*.exe) do (
set "exe_path=%%f"
set "exe_name=%%~nxf"
for %%d in (in out) do (
set /a count+=1
echo [!count!] Adding %%d rule: !exe_name!
netsh advfirewall firewall add rule name="%rule_prefix%!exe_name!" dir=%%d action=block program="!exe_path!" enable=yes >nul
)
)
popd
if !count!==0 (
echo No EXE files found!
)
echo.
echo Total: !count! rules added
pause
goto menu
:delete_rules
cls
echo Delete all block rules? (Y/N)
set /p confirm=
if /i "!confirm!"=="Y" (
echo.
echo Deleting all %rule_prefix% rules...
echo.
set count=0
for /f "tokens=*" %%i in ('netsh advfirewall firewall show rule name^=all ^| findstr /I "%rule_prefix%" ^| findstr /V "@{"') do (
for /f "usebackq tokens=2 delims=:" %%j in ('echo %%i') do (
for /f "tokens=*" %%k in ("%%j") do (
set /a count+=1
echo [!count!] Deleting: %%k
netsh advfirewall firewall delete rule name="%%k"
)
)
)
if !count!==0 (
echo No rules found!
) else (
echo.
echo Total: !count! rules deleted
)
) else (
echo Cancelled
)
pause
goto menu
:open_firewall
start wf.msc
goto menu

複製代碼

		自動登錄	找回密碼
密碼			立即註冊